Maintenance will be performed on git.ligo.org, chat.ligo.org, containers.ligo.org, and docs.ligo.org on Tuesday 22nd September 2020 starting at approximately 9am MST.It is expected to take around 15 minutes and there will be a short period of downtime towards the end of the maintenance window. Please address any comments, questions, or concerns to computing-help@igwn.org.

Commit f973b8d1 authored by Kipp Cannon's avatar Kipp Cannon

add gstlal-inspiral package skeleton

parent 9bcb5f38
gstlal-inspiral.spec
lib/gstlal-inspiral.pc
#!/bin/sh
# Check with the user
echo "This script (re-)builds the source tree's configuration and build system."
read -p "Press CTRL-C to abort, or RETURN to continue... " INPUT
# Get it done
{
{ echo "running aclocal (please ignore \"underquoted\" warnings)..." ; aclocal -I gnuscripts ; } &&
#{ echo "running autoheader..." ; autoheader ; } &&
{ echo "running automake..." ; automake -a -c ; } &&
{ echo "running autoconf..." ; autoconf ; } &&
echo "$0 complete." ;
} || { echo "$0 failed." ; false ; }
This diff is collapsed.
ACLOCAL_AMFLAGS = -I gnuscripts
EXTRA_DIST = gstlal-inspiral.spec
SUBDIRS = debian lib python gst bin
#
# Preamble
#
AC_INIT([gstlal-inspiral],[0.1.0],[gstlal-discuss@gravity.phys.uwm.edu],[gstlal-ugly])
AC_COPYRIGHT([Copyright (C) 2008--2012 Kipp Cannon])
# a file whose existance can be used to use to check that we are in the
# top-level directory of the source tree
AC_CONFIG_SRCDIR([gnuscripts/ltmain.sh])
AC_CONFIG_AUX_DIR([gnuscripts])
AC_CONFIG_MACRO_DIR([gnuscripts])
AM_INIT_AUTOMAKE([1.9 tar-ustar foreign])
AC_CONFIG_FILES([ \
Makefile \
gstlal-inspiral.spec \
debian/Makefile \
lib/gstlal-inspiral.pc \
lib/Makefile \
python/Makefile \
gst/Makefile \
bin/Makefile
])
#
# Move headers into a versioned sub-directory to allow more than one set of
# headers to be installed system-wide. (commented out until this is
# needed)
#
#AC_SUBST([includedir],["\${includedir}/\${PACKAGE}-\${PACKAGE_VERSION}"])
#
# Extra directories
#
AC_SUBST([docdir], ["\${datadir}/doc"])
AC_SUBST([pkgdocdir], ["\${docdir}/\${PACKAGE_NAME}-\${PACKAGE_VERSION}"])
AC_SUBST([pkgconfigdir],["\${libdir}/pkgconfig"])
#
# force /usr/share/ package files into same directory as gstlal
#
AC_SUBST([pkgdatadir],["\${datadir}/gstlal"])
#
# Set the library API info
#
# 0.0.0 Original version
AC_SUBST([LIBAPI], [0])
AC_SUBST([LIBREL], [0])
AC_SUBST([LIBAGE], [0])
AC_SUBST([LIBVERSION], [${LIBAPI}:${LIBREL}:${LIBAGE}])
#
# Check for programs
#
# check for c99 compiler
m4_pattern_allow([AC_PROG_CC_C99])
m4_ifdef([AC_PROG_CC_C99],[AC_PROG_CC_C99],[LALSUITE_AC_PROG_CC_C99])
AC_PROG_CXX
AC_PROG_INSTALL
# libtool incorrectly determines library path on SL6. FIXME: remove when
# no longer needed
case `cat /etc/redhat-release 2> /dev/null` in
"Scientific Linux"*|"CentOS"*)
AC_MSG_NOTICE([hacking round broken libtool multilib support on RedHat systems])
lt_cv_sys_lib_dlsearch_path_spec="/lib64 /usr/lib64"
;;
esac
LT_INIT
PKG_PROG_PKG_CONFIG()
#
# Check for Python
#
AM_PATH_PYTHON([2.6],,)
AX_PYTHON_DEVEL()
# hack to remove default lib dirs from PYTHON_LDFLAGS. only tested on
# Debian and SL6. FIXME: find a way to do this properly
PYTHON_LDFLAGS="`echo $PYTHON_LDFLAGS | sed -e 'sX-L/usr/lib\(64\)\?\(/\)\?[[:space:]]*XXg'`"
# hack to add missing options to PYTHON_LDFLAGS. sigh, what's the point of
# AX_PYTHON_DEVEL!?
PYTHON_LDFLAGS="-module -avoid-version $PYTHON_LDFLAGS"
# force python modules into same directory as gstlal
AC_SUBST([pkgpythondir], ["\${pythondir}/gstlal"])
AC_SUBST([pkgpyexecdir], ["\${pyexecdir}/gstlal"])
#
# CFLAGS
#
AX_CFLAGS_WARN_ALL([AM_CFLAGS])
AM_CFLAGS="$AM_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter" # extra gcc-specific stuff
AC_SUBST([AM_CFLAGS])
#
# LDFLAGS
#
# Turn on error messages for undefined symbols
AM_LDFLAGS="$AM_LDFLAGS -no-undefined"
AC_SUBST([AM_LDFLAGS])
#
# Check for math library
#
AC_CHECK_LIB([m], [main], , [AC_MSG_ERROR([Not found!])])
#
# Check for GStreamer
#
AC_SUBST([GSTREAMER_RELEASE], [0.10])
AC_SUBST([MIN_GSTREAMER_VERSION], [0.10.32])
PKG_CHECK_MODULES([gstreamer], [gstreamer-${GSTREAMER_RELEASE} >= ${MIN_GSTREAMER_VERSION} gstreamer-base-${GSTREAMER_RELEASE} >= ${MIN_GSTREAMER_VERSION}])
AC_SUBST([gstreamer_CFLAGS])
AC_SUBST([gstreamer_LIBS])
AC_SUBST([plugindir], [${libdir}/gstreamer-${GSTREAMER_RELEASE}])
AC_MSG_NOTICE([If you have chosen to install the software in a location not included in your gstreamer's default search path, you might need to add the directory
$plugindir
to your GST_PLUGIN_PATH environment variable.])
AC_SUBST([GSTLAL_PLUGIN_LDFLAGS], ["-module -avoid-version -export-symbols-regex [_]*\(gst_\|Gst\|GST_\|gstlal_\|GstLAL_\|GSTLAL_\).*"])
# Check for availability of GstBaseParse class (starting in 0.10.33)
CFLAGS_saved="$CFLAGS"
CFLAGS="$gstreamer_CFLAGS"
AC_COMPILE_IFELSE(
[AC_LANG_PROGRAM([#include <gst/base/gstbaseparse.h>])],
[HAVE_GSTBASEPARSE=yes
AC_DEFINE([HAVE_GST_BASEPARSE], [1], [Define if GstBaseParse class is available.])],
[HAVE_GSTBASEPARSE=no]
)
CFLAGS="$CFLAGS_saved"
AM_CONDITIONAL([COND_GSTBASEPARSE], [test "x${HAVE_GSTBASEPARSE}" == "xyes"])
#
# Check for GStreamer Video Library
#
AC_SUBST([GSTREAMER_VIDEO_RELEASE], [0.10])
AC_SUBST([MIN_GSTREAMER_VIDEO_VERSION], [0.10.32])
PKG_CHECK_MODULES([gstreamer_video], [gstreamer-video-${GSTREAMER_VIDEO_RELEASE} >= ${MIN_GSTREAMER_VIDEO_VERSION}])
AC_SUBST([gstreamer_video_CFLAGS])
AC_SUBST([gstreamer_video_LIBS])
#
# Check for GStreamer Audio Library
#
AC_SUBST([GSTREAMER_AUDIO_RELEASE], [0.10])
AC_SUBST([MIN_GSTREAMER_VIDEO_VERSION], [0.10.32])
PKG_CHECK_MODULES([gstreamer_audio], [gstreamer-audio-${GSTREAMER_VIDEO_RELEASE} >= ${MIN_GSTREAMER_VIDEO_VERSION}])
AC_SUBST([gstreamer_audio_CFLAGS])
AC_SUBST([gstreamer_audio_LIBS])
#
# Check for PyGObject
#
PKG_CHECK_MODULES([pygobject], [pygobject-2.0])
AC_SUBST([pygobject_CFLAGS])
AC_SUBST([pygobject_LIBS])
#
# Check for NumPy
#
AX_PYTHON_MODULE(numpy, fatal)
NUMPY_CFLAGS=-I`$PYTHON -c "import numpy;print (numpy.get_include());"`
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS ${PYTHON_CPPFLAGS} ${NUMPY_CFLAGS}"
AC_CHECK_HEADER([numpy/arrayobject.h],
[PYTHON_CPPFLAGS="${PYTHON_CPPFLAGS} ${NUMPY_CFLAGS}"],
[AC_MSG_ERROR([Numpy extension header not found])],
[#include "Python.h"])
CFLAGS="$old_CFLAGS"
#
# Check for LAL
#
PKG_CHECK_MODULES([LAL], [lal >= 6.7.0 lalframe >= 1.0.5 lalmetaio >= 1.0.4 lalsupport lalsimulation >= 0.2.0 lalburst >= 1.1.2 lalinspiral >= 1.3.0])
AC_SUBST([LAL_CFLAGS])
AC_SUBST([LAL_LIBS])
#
# Check for gstlal
#
PKG_CHECK_MODULES([GSTLAL], [gstlal >= 0.3.0])
AC_SUBST([GSTLAL_CFLAGS])
AC_SUBST([GSTLAL_LIBS])
#
# Check for GSL
#
PKG_CHECK_MODULES([GSL], [gsl])
AC_SUBST([GSL_CFLAGS])
AC_SUBST([GSL_LIBS])
#
# Output configure information
#
AC_PROG_MAKE_SET
AC_OUTPUT
EXTRA_DIST = \
changelog \
compat \
control \
copyright \
rules
gstlal-inspiral (0.1.0-1) unstable; urgency=low
* First release
-- Kipp Cannon <kipp.cannon@ligo.org> Wed, 07 Nov 2012 12:00:00 -0500
Source: gstlal-inspiral
Maintainer: Carsten Aulbert <carsten.aulbert@aei.mpg.de>
Section: lscsoft
Priority: optional
Standards-Version: 3.9.2
Build-Depends:
debhelper (>= 8),
python-dev,
gstlal-dep,
python-gobject-dev,
lal-dev,
lalframe-dev,
lalmetaio-dev,
lalburst-dev,
lalinspiral-dev,
fakeroot,
autoconf,
pkg-config,
gstlal (>=0.4.0)
Package: gstlal-inspiral
Architecture: any
Depends: ${shlibs:Depends}, ${misc:Depends}
Description: GStreamer version of LAL (inspiral part)
gstlal provides a suite of GStreamer elements that expose
gravitational-wave data analysis tools from the LAL library for use
in GStreamer signal-processing pipelines. Examples include an element
to add simulated gravitational waves to an h(t) stream, and source
elements that can provide data from .gwf frame files or NDS
servers to a GStreamer pipeline.
#!/usr/bin/make -f
%:
. /opt/lscsoft/gst/etc/gstlal.sh; dh $@
override_dh_auto_test:
. /opt/lscsoft/gst/etc/gstlal.sh; export PYTHONPATH=$$(pwd)/python; dh $@
override_dh_shlibdeps:
. /opt/lscsoft/gst/etc/gstlal.sh; dh "$@" -Xlibgstaudio-0.10.so.0
Markdown is supported
0% or
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment